您现在的位置: IOS教程網 >> IOS系統 >  >> iOS 程式開發 >> iOS 開發基礎

聊聊魔性的動畫引擎 pop:源碼裡的六個關鍵設計

編輯:iOS 開發基礎

iOS 完全可以自己造一個動畫引擎,CADisplayLink 就是那把鑰匙,pop 正是建立在它之上,而且比原生 Core Animation 更強大好用。

最典型的差異是:當 ViewController 側滑返回時,系統會把 Core Animation 的動畫停掉,而基於 CADisplayLink 的動畫不會中斷。網易雲音樂播放頁側滑時專輯封面依然穩穩旋轉,靠的就是這個特性。

一、實用的宏

#define POP_ARRAY_COUNT(x) sizeof(x) / sizeof(x[0])

#define FB_PROPERTY_GET(stype, property, ctype) \
- (ctype)property { \
    return ((stype *)_state)->property; \
}

#define FB_PROPERTY_SET(stype, property, mutator, ctype, ...) \
- (void)mutator (ctype)value { \
    if (value == ((stype *)_state)->property) \
        return; \
    ((stype *)_state)->property = value; \
    __VA_ARGS__ \
}

#define FB_PROPERTY_SET_OBJ_COPY(stype, property, mutator, ctype, ...) \
- (void)mutator (ctype)value { \
    if (value == ((stype *)_state)->property) \
        return; \
    ((stype *)_state)->property = [value copy]; \
    __VA_ARGS__ \
}

二、判定值的數據類型

pop 明確列出了自己支持的值類型:

const POPValueType kPOPAnimatableSupportTypes[10] = {
    kPOPValueInteger,
    kPOPValueFloat,
    kPOPValuePoint,
    kPOPValueSize,
    kPOPValueRect,
    kPOPValueEdgeInsets,
    kPOPValueColor,
    kPOPValueSCNVector3,
    kPOPValueSCNVector4
};

具體判別依賴 @encode 指令,把類型編碼的內部字符串與 objcType 逐一比對:

static bool FBCompareTypeEncoding(const char *objctype, POPValueType type) {
    switch (type) {
        case kPOPValueFloat:
            return (strcmp(objctype, @encode(float)) == 0
                    || strcmp(objctype, @encode(double)) == 0);

        case kPOPValuePoint:
            return (strcmp(objctype, @encode(CGPoint)) == 0
#if !TARGET_OS_IPHONE
                    || strcmp(objctype, @encode(NSPoint)) == 0
#endif
                    );

        case kPOPValueSize:
            return (strcmp(objctype, @encode(CGSize)) == 0
#if !TARGET_OS_IPHONE
                    || strcmp(objctype, @encode(NSSize)) == 0
#endif
                    );

        case kPOPValueRect:
            return (strcmp(objctype, @encode(CGRect)) == 0
#if !TARGET_OS_IPHONE
                    || strcmp(objctype, @encode(NSRect)) == 0
#endif
                    );

        case kPOPValueEdgeInsets:
#if TARGET_OS_IPHONE
            return strcmp(objctype, @encode(UIEdgeInsets)) == 0;
#else
            return false;
#endif

        case kPOPValueAffineTransform:
            return strcmp(objctype, @encode(CGAffineTransform)) == 0;

        case kPOPValueTransform:
            return strcmp(objctype, @encode(CATransform3D)) == 0;

        case kPOPValueRange:
            return strcmp(objctype, @encode(CFRange)) == 0
                || strcmp(objctype, @encode (NSRange)) == 0;

        case kPOPValueInteger:
            return (strcmp(objctype, @encode(int)) == 0
                    || strcmp(objctype, @encode(unsigned int)) == 0
                    || strcmp(objctype, @encode(short)) == 0
                    || strcmp(objctype, @encode(unsigned short)) == 0
                    || strcmp(objctype, @encode(long)) == 0
                    || strcmp(objctype, @encode(unsigned long)) == 0
                    || strcmp(objctype, @encode(long long)) == 0
                    || strcmp(objctype, @encode(unsigned long long)) == 0);

        case kPOPValueSCNVector3:
#if SCENEKIT_SDK_AVAILABLE
            return strcmp(objctype, @encode(SCNVector3)) == 0;
#else
            return false;
#endif

        case kPOPValueSCNVector4:
#if SCENEKIT_SDK_AVAILABLE
            return strcmp(objctype, @encode(SCNVector4)) == 0;
#else
            return false;
#endif

        default:
            return false;
    }
}

三、把值標準化為 Vector

以 CGRect 為例:

case kPOPValueRect:
    vec = Vector::new_cg_rect([value CGRectValue]);
Vector *Vector::new_cg_rect(const CGRect &r) {
    Vector *v = new Vector(4);
    v->_values[0] = r.origin.x;
    v->_values[1] = r.origin.y;
    v->_values[2] = r.size.width;
    v->_values[3] = r.size.height;
    return v;
}

Vector 只靠 size_t _count 與 CGFloat *_values 兩個成員,就把所有受支持的類型抽象到同一層,實現了徹底解耦。這還帶來一個額外好處:假如你把一個 kPOPLayerBounds 的屬性動畫的 toValue 錯賦成了 NSNumber,由於 _values 是數組指針,不會數組越界崩潰,最壞結果只是動畫表現不如預期。

四、基於 NSRunLoop 的動畫更新機制

- (void)_scheduleProcessPendingList {
    // see WebKit for magic numbers, eg https://trac.webkit.org/changeset/166540
    static const CFIndex CATransactionCommitRunLoopOrder = 2000000;
    static const CFIndex POPAnimationApplyRunLoopOrder = CATransactionCommitRunLoopOrder - 1;

    // lock
    OSSpinLockLock(&_lock);

    if (!_pendingListObserver) {
        __weak POPAnimator *weakSelf = self;

        _pendingListObserver = CFRunLoopObserverCreateWithHandler(kCFAllocatorDefault,
                                                                 kCFRunLoopBeforeWaiting | kCFRunLoopExit,
                                                                 false,
                                                                 POPAnimationApplyRunLoopOrder,
                                                                 ^(CFRunLoopObserverRef observer, CFRunLoopActivity activity) {
            [weakSelf _processPendingList];
        });

        if (_pendingListObserver) {
            CFRunLoopAddObserver(CFRunLoopGetMain(), _pendingListObserver, kCFRunLoopCommonModes);
        }
    }

    // unlock
    OSSpinLockUnlock(&_lock);
}

在主線程 RunLoop 上掛一個觀察者,監聽 kCFRunLoopBeforeWaiting 與 kCFRunLoopExit,在回調抵達時批量處理 _pendingList 裡的動畫。順序值刻意壓在 CATransaction 提交之前一位,保證動畫取值領先於渲染提交。

五、更新動畫的回調數組

static POPStaticAnimatablePropertyState _staticStates[] = {
    /* CALayer */

    {kPOPLayerBackgroundColor,
        ^(CALayer *obj, CGFloat values[]) {
            POPCGColorGetRGBAComponents(obj.backgroundColor, values);
        },
        ^(CALayer *obj, const CGFloat values[]) {
            CGColorRef color = POPCGColorRGBACreate(values);
            [obj setBackgroundColor:color];
            CGColorRelease(color);
        },
        kPOPThresholdColor
    },

    {kPOPLayerBounds,
        ^(CALayer *obj, CGFloat values[]) {
            values_from_rect(values, [obj bounds]);
        },
        ^(CALayer *obj, const CGFloat values[]) {
            [obj setBounds:values_to_rect(values)];
        },
        kPOPThresholdPoint
    },

    ...

每個屬性都配一對「讀取 / 寫入」閉包,加上一個閾值,相當於把不同動畫行為封裝成模板,調用側只需統一入口:

// write value
write(obj, currentVec->data());

六、動畫插值的動態實現

switch (type) {
    case kPOPAnimationSpring: {
        advanced = advance(time, dt, obj);
        break;
    }

    case kPOPAnimationDecay: {
        advanced = advance(time, dt, obj);
        break;
    }

    case kPOPAnimationBasic: {
        advanced = advance(time, dt, obj);
        computedProgress = true;
        break;
    }

    case kPOPAnimationCustom: {
        customFinished = [self _advance:obj currentTime:time elapsedTime:dt] ? false : true;
        advanced = true;
        break;
    }

    default:
        break;
}

四類插值算法:Spring、Decay、Basic 與 Custom。以 Basic 為例:

bool advance(CFTimeInterval time, CFTimeInterval dt, id obj) {
    // default timing function
    if (!timingFunction) {
        ((POPBasicAnimation *)self).timingFunction = [CAMediaTimingFunction functionWithName:kCAMediaTimingFunctionDefault];
    }

    // solve for normalized time, aka progresss [0, 1]
    CGFloat p = 1.0f;

    if (duration > 0.0f) {
        // cap local time to duration
        CFTimeInterval t = MIN(time - startTime, duration) / duration;
        p = POPTimingFunctionSolve(timingControlPoints, t, SOLVE_EPS(duration));
        timeProgress = t;
    } else {
        timeProgress = 1.;
    }

    // interpolate and advance
    interpolate(valueType, valueCount, fromVec->data(), toVec->data(), currentVec->data(), p);
    progress = p;
    clampCurrentValue();

    return true;
}

依照給定的 timingFunction,用 POPTimingFunctionSolve 解出貝塞爾曲線上的進度,再套上線性混合公式 #define MIX(a, b, f) ((a) + (f) * ((b) - (a))),就得到了這一幀的插值結果。

小結

pop 裡還有不少有意思的角落,比如 TransformationMatrix 中的矩陣運算,這裡就先不往 WebCore 底層挖了。總的來說,無論性能(C++ 混編)、易用性還是容錯能力,pop 都具備一個引擎該有的素質;而它刻意做出與 Core Animation 相似的接口,也讓上手成本極低。

本文作者:伯樂在線 - Hawk0620

  1. 上一篇文章:
  2. 下一篇文章:
蘋果刷機越獄教程| IOS教程問題解答| IOS技巧綜合| IOS7技巧| IOS8教程
Copyright © IOS教程網 All Rights Reserved